效果演示视频(apple设备无法播放):

用到的硬件: ESP8266-NodeMCU开发板、继电器模块、常开门禁开关、杜邦线若干。

在巴法云建立帐号并添加MQTT设备云,将私钥复制到下方代码ID_MQTT变量中

米家添加设备:我的 -> 其他平台设备 -> 巴法,按提示绑定巴法云帐号

使用Arduino将以下程序烧录至esp8266开发板:

/*
* 智能语言控制控制，支持同时天猫、小爱、小度、google Assistent控制
* 也同时支持web控制、小程序控制、app控制，定时控制等
* 项目示例：通过发送on或off控制开关
* 官网：bemfa.com
*/

#include <ESP8266WiFi.h>               //默认，加载WIFI头文件
#include <DNSServer.h>
#include <ESP8266WebServer.h>
#include <WiFiManager.h>
#include <Ticker.h> 
//#include <PubSubClient.h>
#include "PubSubClient.h"              //默认，加载MQTT库文件         

WiFiClient espClient;  //wifi客户端模式
PubSubClient client(espClient);
Ticker ticker;  //定时器对象

//********************需要修改的部分*******************//
#define ID_MQTT  "xxx"     //用户私钥，控制台获取

#define D1 5   //D1
#define D2 4   //D2
const char*  topic = "light002";        //主题名字，与巴法云控制台的主题一致
const int B_led = D1;       //引脚值，此引脚用于连接继电器的信号端
const int led_switch = D2;       //引脚值，此引脚用于连接继电器的信号端
//**************************************************//

const char* mqtt_server = "bemfa.com"; //默认，MQTT服务器
const int mqtt_server_port = 9501;      //默认，MQTT服务器端口
int count;    // Ticker计数用的变量
int state = 0; //灯的状态

// 建立WiFiManager对象
WiFiManager wifiManager;  

//灯光函数及引脚定义
void turnOnLed();
void turnOffLed();

//计数
void tickerCount(){
  count++;
}

// 连接MQTT服务器
void reconnect() {
    Serial.print("Attempting MQTT connection...");
    // Attempt to connect
    if (client.connect(ID_MQTT)) {
      Serial.println("connected");
      Serial.print("subscribe:");
      Serial.println(topic);
      //订阅主题，如果需要订阅多个主题，可发送多条订阅指令client.subscribe(topic2);client.subscribe(topic3);
      client.subscribe(topic);
    } else {
      Serial.print("failed, rc=");
      Serial.println(client.state());
      Serial.println(" try again in 1 seconds");
      // Wait 5 seconds before retrying
      delay(1000);
    }
}

// 收到信息后的回调函数
void receiveCallback(char* topic, byte* payload, unsigned int length) {
  Serial.print("Topic:");
  Serial.println(topic);
  String msg = "";
  for (int i = 0; i < length; i++) {
    msg += (char)payload[i];
  }
  Serial.print("Msg:");
  Serial.println(msg);
  if (msg == "on") {//如果接收字符on，亮灯
    turnOnLed();//开灯函数
  } else if (msg == "off") {//如果接收字符off，关灯
    turnOffLed();//关灯函数
  }
  msg = "";  
}

//开灯
void turnOnLed() {
  Serial.println("turn on light");
  digitalWrite(B_led, HIGH);
  state = 1;
}

//关灯
void turnOffLed() {
  Serial.println("turn off light");
  digitalWrite(B_led, LOW);
  state = 0;
}

// 发布信息
void pubMQTTmsg(){   
    // 建立发布主题
    //巴法云个性设置，推送消息时：主题名后加/set推送消息，表示向所有订阅这个主题的设备们推送消息，
    //假如推送者自己也订阅了这个主题，消息不会被推送给它自己，以防止自己推送的消息被自己接收。
    String topicString = "light002/set" ;
    char publishTopic[topicString.length() + 1];  //转换成字符数组
    strcpy(publishTopic, topicString.c_str());
   
    // 建立发布信息,当前D1引脚状态
    String messageString;
    if(digitalRead(B_led)){
      messageString = "on"; 
    } else {
      messageString = "off"; 
    }       
    char publishMsg[messageString.length() + 1];   //转换成字符数组
    strcpy(publishMsg, messageString.c_str());
    
    // 实现ESP8266向主题发布信息,并在串口监视器显示出来
    if(client.publish(publishTopic, publishMsg)){
      Serial.println("Publish Topic:");
      Serial.println(publishTopic);
      Serial.println("Publish message:");
      Serial.println(publishMsg);    
    } else {
      Serial.println("Message Publish Failed."); 
    }
}

//程序入口
void setup() {
  pinMode(B_led, OUTPUT); //设置引脚为输出模式
  pinMode(led_switch, OUTPUT); // 开关引脚为输入模式
  digitalWrite(B_led, LOW);//默认引脚上电低电平
  Serial.begin(9600);     //设置波特率9600
  
  //********************自动配置网络************************  
//  wifiManager.setTimeout(20);
  wifiManager.setConfigPortalTimeout(120);
  // 自动连接WiFi。以下语句的参数是连接ESP8266时的WiFi名称
//  wifiManager.autoConnect("AutoConnectAP");  
  // 如果您希望该WiFi添加密码，可以使用以下语句：
   wifiManager.autoConnect("8266"); 
  //重置wifi设置
  // wifiManager.resetSettings();
  // WiFi连接成功后将通过串口监视器输出连接成功信息 
  Serial.println(""); 
  Serial.print("ESP8266 Connected to ");
  Serial.println(WiFi.SSID());              // WiFi名称
  Serial.print("IP address:\t");
  Serial.println(WiFi.localIP());           // IP
  //*******************************************************  
    
  client.setServer(mqtt_server, mqtt_server_port);//设置mqtt服务器
  client.setCallback(receiveCallback); //mqtt消息处理  
    
  ticker.attach(1, tickerCount); // Ticker定时对象
  
  Serial.println("setup结束");

}


//循环执行 
void loop() {

  int val = digitalRead(B_led);
  int ctl_val = digitalRead(led_switch);



  if(ctl_val == 1){//按键按下
      delay(400);
      state = !state;
      digitalWrite(B_led, state);
      digitalWrite(led_switch, LOW);
      int ctl_val = digitalRead(led_switch);
      Serial.print("开2关值为 :\t");
      Serial.println(ctl_val);
    }

  
     

    if (client.connected()) {
      client.loop();
      if (count >= 10){ // 每隔10秒钟发布一次信息
          pubMQTTmsg();
          count = 0;
      }
    }else{
      // mqtt链接断开,并且已连接上AP,则重连mqtt
      if(wifiManager.getWLStatusString().equals("WL_CONNECTED")){
          reconnect();
      }
    }

}

继电器及门禁开关分别使用D1、D2引脚作为信号触发,

D1在收到开灯指令时输出高电平触发继电器动作,从而点亮灯泡

D2连接门禁开关,门禁开关另一端连接开发板3.3V引脚,在按下开关时,将D2引脚拉高,作为手动控制灯开关:按下并松开开关,灯将点亮或熄灭

开发板断网时仍可通过门禁开关控制灯光

烧录完成后开发板将自动重启,首次未配网时,开发板将启用ssid为8266的接入点,使用无线设备连接该热点,进入网络认证页面完成网络配置.

接线图如下:

两条橙色线分别接入3.3v及D2引脚

绿色线接5v引脚给继电器供电

蓝色线接GND引脚给继电器供电

灰色线接D1引脚作为继电器信号线

继电器设置为高电平触发模式

继电器COM接灯开关内的220V火线

继电器NO接灯的控制线

开发板上电或重启时,继电器为断开状态,COM口与NO为开路状态,灯不点亮

发送开灯指令时,继电器吸合,COM口与NO为短路状态,灯会被点亮

使用小爱语音(提前在米家绑定巴法云)控制开关或者手动发送mqtt指令on、off可以完成控制

附上硬件购买截图

更新:通过siri控制

这里使用php编写一段发布mqtt消息的代码:

<?php
/**
 * Created by PhpStorm.
 * User: ZXQ
 * Date: 2024/3/9
 * Time: 23:43
 */
require('./phpMQTT.php');



function console_log($data){
    echo("<script>console.log(".json_encode($data).")</script>");
}

$server   = 'bemfa.com';
$port     = 9501;
$clientId = 'xx';
$username = null;
$password = null;
$clean_session = false;

if (($_SERVER['REQUEST_METHOD']==='GET')){
    $action = $_GET['action'];
    if ($action=='on'){

        $mqtt = new Bluerhinos\phpMQTT($server, $port, $clientId);

        if ($mqtt->connect(true, NULL, $username, $password)) {
            //public用法：publish($topic主题, $content内容, $qos = 0, $retain = false): void
            $mqtt->publish('light002/set', 'on', 0, false);
            $mqtt->close();
        } else {
            echo "Time out!\n";
        }


    }
    if ($action=='off'){
        $mqtt = new Bluerhinos\phpMQTT($server, $port, $clientId);
        if ($mqtt->connect(true, NULL, $username, $password)) {
            //public用法：publish($topic主题, $content内容, $qos = 0, $retain = false): void
            $mqtt->publish('light002/set', 'off', 0, false);
            $mqtt->close();
        } else {
            echo "Time out!\n";
        }

    }

    echo json_encode("success");
}

phpMQTT.php来自phpMQTT.php

部署完成后,在IOS中添加两条快捷指令,分别为开灯和关灯,操作选择"从URL获取内容",输入开关灯对应URL,然后直接对Siri说开灯或者关灯就可以了,虽说这种方式有点low,但也算实现了吧...